ESP32 Web Server Menggunakan Arduino IDE

Haloo teman teman semua!!!
Kembali lagi bersama saya Daniel, kali ini saya akan berbagi pengalaman ESP32 saya tentang pembuatan web server pada ESP32 menggunakan aplikasi Arduino IDE.
Pembuatan Web Server pada ESP32 tidaklah terlalu sulit karena saya berhasil membuatnya dalam sekali coba padahal saya baru pertama kali membuat Web Server di ESP32. Saya berterima kasih kepada website www.randomnerdtutorials.com karena telah banyak membantu saya belajar ESP32 termasuk dalam pembuatan Web Server ini. Teman teman juga dapat mengunjungi website tersebut jika ingin belajar lebih dalam ESP32. Disana banyak sekali proyek yang dibuat menggunakan ESP32. Saya yakin teman teman semua pasti bisa dalam belajar ESP32, karena saya saja orang awam bisa mencobanya begitu pula dengan kalian :D. Tanpa banyak berbasa basi lagi, berikut akan saya jelaskan cara saya membuatnya.

Alat dan Bahan

Berikut akan saya lampirkan alat atau bahan yang diperlukan dalam pembuatan web server ini.
1. ESP32 DEVKIT V1 Development Board dan Kabel Type A to Micro USB



2. Lampu LED 5mm (2)



3. Kabel jumper Female to Male (3)



4. Resistor 330 Ohm (2)



5. Breadboard



6. Laptop / PC yang sudah memiliki aplikasi Arduino IDE

Cara Pembuatan

Berikut adalah langkah - langkah dalam pembuatan Web Server ESP32 menggunakan aplikasi Arduino IDE. Mohon diikuti dengan seksama.
1.  Ambil alat alat yang sudah disiapkan sebelumnya, lalu susunlah alat alat tersebut mengikuti skema rangkaian sebagai berikut.




2. Hubungkan ESP32 dengan laptop menggunakan kabel yang sudah disiapkan tadi lalu masukkan kode berikut ke dalam aplikasi Arduino IDE dan jalankan (Compile). Tunggu hingga proses selesai.

/*********
  Rui Santos
  Complete project details at https://randomnerdtutorials.com  
*********/

// Load Wi-Fi library
#include <WiFi.h>

// Replace with your network credentials
const char* ssid     = "";
const char* password = "";

// Set web server port number to 80
WiFiServer server(80);

// Variable to store the HTTP request
String header;

// Auxiliar variables to store the current output state
String output26State = "off";
String output27State = "off";

// Assign output variables to GPIO pins
const int output26 = 26;
const int output27 = 27;

void setup() {
  Serial.begin(115200);
  // Initialize the output variables as outputs
  pinMode(output26, OUTPUT);
  pinMode(output27, OUTPUT);
  // Set outputs to LOW
  digitalWrite(output26, LOW);
  digitalWrite(output27, LOW);

  // Connect to Wi-Fi network with SSID and password
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  server.begin();
}

void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients

  if (client) {                             // If a new client connects,
    Serial.println("New Client.");          // print a message out in the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected()) {            // loop while the client's connected
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();
            
            // turns the GPIOs on and off
            if (header.indexOf("GET /26/on") >= 0) {
              Serial.println("GPIO 26 on");
              output26State = "on";
              digitalWrite(output26, HIGH);
            } else if (header.indexOf("GET /26/off") >= 0) {
              Serial.println("GPIO 26 off");
              output26State = "off";
              digitalWrite(output26, LOW);
            } else if (header.indexOf("GET /27/on") >= 0) {
              Serial.println("GPIO 27 on");
              output27State = "on";
              digitalWrite(output27, HIGH);
            } else if (header.indexOf("GET /27/off") >= 0) {
              Serial.println("GPIO 27 off");
              output27State = "off";
              digitalWrite(output27, LOW);
            }
            
            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the on/off buttons 
            // Feel free to change the background-color and font-size attributes to fit your preferences
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #4CAF50; border: none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color: #555555;}</style></head>");
            
            // Web Page Heading
            client.println("<body><h1>ESP32 Web Server</h1>");
            
            // Display current state, and ON/OFF buttons for GPIO 26  
            client.println("<p>GPIO 26 - State " + output26State + "</p>");
            // If the output26State is off, it displays the ON button       
            if (output26State=="off") {
              client.println("<p><a href=\"/26/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/26/off\"><button class=\"button button2\">OFF</button></a></p>");
            } 
               
            // Display current state, and ON/OFF buttons for GPIO 27  
            client.println("<p>GPIO 27 - State " + output27State + "</p>");
            // If the output27State is off, it displays the ON button       
            if (output27State=="off") {
              client.println("<p><a href=\"/27/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/27/off\"><button class=\"button button2\">OFF</button></a></p>");
            }
            client.println("</body></html>");
            
            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
          } else { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}
NB : Di bagian SSID dan Password, isilah sesuai dengan WiFi teman - teman. Contohnya milik saya, saya terkoneksi dengan WiFi yang memiliki SSID dan Password sebagai berikut.



3. Buka Serial Monitor lalu tekan tombol EN pada ESP32. Dalam serial Monitor tersebut, akan ada tertulis IP Addrress dari ESP32 milik kita.



4. Salin IP Address tersebut lalu masukkan ke dalam mesin pencarian. Lalu akan muncul tampilan web sebagai berikut.



5. Untuk mencoba menyalakan lampu LED, coba tekan tombol ON yang terdapat pada website tersebut. Jika lampu LED milikmu yang terhubung ke ESP32 telah berhasil menyala, maka itu artinya kamu telah berhasil membuat ESP32 Web Server milikmu sendiri. Berikut adalah video hasil percobaan saya.



Kesimpulan

Pada zaman sekarang ini, web server sangatlah penting dalam kehidupan bermasyarakat untuk dapat membuat hidup menjadi lebih praktis. Contoh masalah yang ada saat ini adalah pandemic virus Corona yang terus memakan korban semakin banyak dari hari ke hari. Proses penularan virus ini ditangani dengan menggunakan Web Server untuk berkomunikasi antar sesama manusia. Selain itu, dengan adanya pembuatan web server ini, kita jadi dapat mengatur segala alat elektronik di rumah melalui device yang ada di genggaman tangan kita.
Dalam pembuatan proyek ini, constraint atau hambatan yang saya alami adalah saya kesulitan untuk membeli alat yang kurang karena sekarang ini pemerintah menghimbau agar masyarakat tidak keluar rumah. Hal ini dilakukan agar proses penyebaran virus dapat berkurang dan dihentikan. Oleh karena itu, saya menangani masalah ini dengan membelinya secara online.
Sekianlah penjelasan dari saya. Bila ada kesulitan atau ada yang mau ditanyakan, silahkan menuliskannya pada kolom komentar. Sesegera mungkin saya akan menjawabnya bila saya sudah membacanya. Atas perhatian teman teman sekalian, saya ucapkan terimakasih. Sampai jumpa di artikel blog yang berikutnya....
Semangatlah dalam mencoba dan jangan pantang menyerah. Kita semua pasti bisaa!!!

Komentar

Posting Komentar

Postingan populer dari blog ini

Weather Station Visualization with ESP32

Gambar
Haloo teman - teman semua !!! Pada kesempatan kali ini aku akan menjelaskan mengenai bagaimana sih cara membuat visualisasi data berupa grafik dll dari alat pengukur cuaca BME280, yang tentunya menggunakan media ESP32. Sebelumnya aku mengucapkan banyak terimakasih kepada website www.randomnerdtutorials.com yang telah berbagi banyak informasi dan pengetahuan mengenai ESP32 yang membuat aku lebih mudah dalam mengerjakan proyek ini. Berkat adanya web tersebut, dalam sekali percobaan aku langsung berhasil membuat proyek ini. Aku sendiri pun awalnya ga percaya tapi ternyata usahaku yang serius langsung membuahkan hasil. Tanpa banyak berbasa - basi lagi langsung aja kita masuk ke dalam pembahasan bagaimana caranya. Cekidott!!! FileSystem Uploader Plugin Sebelum memulai langkahnya, kalian harus menngintall plugin dibawah ini kedalam aplikasi arduino IDE kalian agar nantinya file HTML yang kita buat, dapat diupload dan dibaca oleh ESP32 kita. Link downloadnya dapat anda klik disini : 
Baca selengkapnya

Membuat LED Blink pada ESP32

Gambar
Halo teman-teman !! Kembali lagi bersama saya Daniel Hutabalian. Kali ini saya akan berbagi mengenai proyek saya tentang ESP32. Apa itu ESP32 ? ESP32 adalah SoC (System On Chip) Microcontroller. Saya juga belum terlalu mengerti tentang cara kerja ESP32 karena saya juga masih baru belajar dari dosen saya mengenai cara penggunaan ESP32. Oleh karena itu, sekarang ini saya akan membagikan kisah saya hingga saya berhasil menjalankan program LED Blink pada ESP32. Awalnya saya bingung ESP32 yang dibutuhkan itu berapa pin karena ESP32 mempunyai berbagai variasi pin. Contohnya ada yang 30 pin, 36 pin dan lain sebagainnya. Kemudian, ESP32 yang dibutuhkan ternyata dibebaskan untuk jumlah pinnya. Hanya saja untuk yang 36 pin agak sedikit tricky karena ada beberapa hal yang harus dilakukan pada ESP32 agar program yang dimasukkan tidak error. Kemudian, saya berencana untuk membeli ESP32 yang 30 pin karena cara pakainya yang cukup sederhana. Di Bandung, terdapat toko elektronik yang menjual
Baca selengkapnya

Cara Menggunakan I2C Display dengan ESP32

Gambar
Haloo semuaaaa !! Kembali lagi bersama saya Daniel Hutabalian di artikel tentang ESP32. Sesuai dengan judul, pada artikel kali ini saya akan membahas cara menggunakan I2C Display pada ESP32 untuk menampilkan tulisan pada LCD nya tersebut. Berikut adalah penjelasannya.Selamat membaca dan menyimak !! Sebelum masuk ke pembahasannya, saya ingin menceritakan pengalaman saya dalam membuat proyek ini. Awalnya saya ingin membeli I2C Display langsung setelah tugas ini diberikan, karena alat yang saya butuhkan tinggal itu. Tetapi pada hari itu saya batal untuk membelinya dan mencoba menanyakan kepada kakak saya yang Teknik Elektro siapa tau dia mempunyai alat tersebut. Ternyata, alat tersebut dimiliki oleh kakak saya ini dan kondisi barangnya pun masih sangat baik. Saya pun senang sekali ketika melihatnya membawakan I2C Display nya kepada saya. Akhirnya setelah semua peralatan lengkap, saya pun langsung mencoba mengerjakan proyek ini. Berikut adalah alat - alat yang dibutuhkan. 1. ESP32 (D
Baca selengkapnya